Verilerinizi Excelde Sayma ve Toplama

Verilerinizi Excelde Sayma ve Toplama

Tüm Excel Kullanıcıları İçin Yararlı Olacak Formüller

Sayma ve toplama işlemleri elektronik tabloda temel işlemlerdir ve bunları kullanarak Microsoft Excel uygulamasında daha birçok şeyi yapabilirsiniz. Bu makalede, sayma ve toplama ile ilgili olarak açıklanan formüller her Excel kullanıcısının bilmesi gereken bilgilerdir. Formüller Şekil 1'deki çalışma sayfasını örnek almıştır.

Şekil 1'deki 12 veri satırı ortalama bir şirketin satış ile ilgili bilgilerini içerir ve üç alandan oluşur: satış temsilcisi, satışın yapıldığı ay ve satışın miktarı. Sayma ve toplama formüllerine ilişkin olarak verilen örnekler küçük bir şirketin bu verileri nasıl çözümleyebileceğini gösterecektir. Verileriniz daha geniş çaplı olabileceği gibi, farklı amaçlar için de toplanmış olabilir, ancak formüller hep aynı şekilde işler. Örnek formüller açıklandıktan sonra, Şekil 1'deki veriler temel alınarak çıkan sonuçlar verilecektir.


Şekil 1: Örnek Excel çalışma sayfası



Toplama ve Sayma
Bütçeniz için, satış istatistikleri için veya envanter için olsun, sayıları toplamak sıkça yapılan bir işlemdir. Bu örneklerde SUM işlevini kullanın. Bu formüller sayıların toplamını C sütununda vermektedir:

  • Belirli bir aralıktaki değerleri toplama: =SUM(C2:C13)
  • Formül sonucu: 6,125
  • Tüm aralıktaki değerleri toplama: =SUM(C:C). Varolan bir tabloya sık sık yeni veriler eklenir. Bu nedenle, satırların sayısı değişebilir. Bu formül tüm sütunu toplar, böylece yeni veri eklendiğinde formülün düzenlenmesi gereğini ortadan kaldırır. Değerleri saymak için, COUNT işlevini kullanın. Bu işlev, bir aralıktaki değerlerin sayısını verir ve kaç hücrenin sayısal bilgi içerdiğini çabuk bir şekilde gösterir. Örneğin, satış yapılan ayların sayısını öğrenmek istediğinizde işinize yarayabilir.

·  Bir aralıktaki değerleri sayma: =COUNT(C2:C13)

·  Formül sonucu: 12

·  Tüm aralıktaki değerleri sayma: =COUNT(C:C) C sütununda 13 giriş olmasına karşın, bu formüller 12 sonuç veriyor, çünkü COUNT işlevi yalnızca sayısal değerleri sayar. Bir aralıkta, bilgi içeren tüm hücrelerin sayılmasını istiyorsanız, COUNTA işlevini kullanın. Örneğin, =COUNTA(A:A). Bu formül size 13 sonuç verecektir.

Tek Bir Koşul Kullanarak Koşullu Sayma ve Toplama Yapma
Çoğu durumda, kayıtların tümünü saymak veya toplamak yerine, belirli bir koşula uyan kayıtları (örneğin, yalnızca belirli bir satış temsilcisi tarafından yapılan satışlar) görmek istersiniz. Bu tür sonuçları almak için COUNTIF ve SUMIF işlevlerini kullanın.

Belirli Bir Satış Temsilcisi Tarafından Yapılan Satışları Sayma
Aşağıdaki formül COUNTIF işlevinin normal kullanılışıdır. Jones adlı kişi tarafından yapılan satışları sayar:

  • =COUNTIF(A2:A13,"Jones")
  • Formül sonucu: 4

Bu formülü şu şekilde de yazabilirsiniz: =COUNTIF(A2:A13,"=Jones"). Bir karşılaştırma işareti konmazsa, Excel "eşittir" olarak algılar.

Diğer Satış Temsilcileri Tarafından Yapılan Satışları Sayma
Bu formül Jones dışındaki satış temsilcilerinin yaptığı tüm satışları sayar:

  • =COUNTIF(A2:A13,"<>Jones")
  • Formül sonucu: 8

Tutarı Belirli Bir Değerden Daha Yüksek Olan Satışları Sayma
Bu formül C2:C13 sütunlarında, tutarı belirli bir değerden daha yüksek olan satışları sayar. Bu örnekte, belirlenen değer D1'e girilir. Bu COUNTIF işlevi ikinci ifadede bir hücre başvurusu kabul eder. Ayrıca bu formülde, büyüktür işaretinin (>) hücre başvurusuyla birleştirilmesi için birleştirme işareti (&) kullanıldığına dikkat edin.

  • =COUNTIF(C2:C13,">"&D1)

Tutarı Satış Ortalamasından Daha Yüksek Olan Satışları Sayma
Bu formül ortalama satış tutarını aşan satışların sayısını verir. Formül ayrıca, bir işlevi COUNTIF işlevinin ikinci ifadesi olarak da kullanabileceğinizi göstermektedir:

  • =COUNTIF(C2:C13,">"&AVERAGE(C2:C13))
  • Formul sonucu: 5

Koşullu Toplama
SUMIF işlevi COUNTIF işlevine benzer, ancak bunda fazladan bir ifade daha vardır. İlk ifade hesaplamanın yapıldığı aralığa işaret eder, ikinci ifade kullanılan ölçütü temsil eder, üçüncü ifade ise toplanacak aralıktır.

Belirli Bir Ayda Yapılan Satışları Toplama
Bu formül Ocak ayındaki tüm satışları toplar:

  • =SUMIF(B2:B13,"=Jan",C2:C13)
  • Formül sonucu: 1,925

COUNTIF işlevinde olduğu gibi, karşılaştırma işareti konmazsa, "eşittir" koşulu olduğu varsayılır. Önceki formül şu şekilde yazılabilirdi: =SUMIF(B2:B13,"=Jan",C2:C13).

Diğer Satış Temsilcileri Tarafından Yapılan Satışları Toplama
Bu formül Roger dışındaki satış temsilcileri tarafından yapılan satışları toplar. Formülde "eşit değildir" işareti kullanılmaktadır:

  • =SUMIF(A2:A13,"<>Rogers",C2:C13)
  • Formül sonucu: 4,425

Belirli Bir Değerden Daha Yüksek Olan Satışları Toplama
Bu formül 500'den büyük olan tüm değerleri toplar. Formülde, değerlendirilen koşul toplanan aralıkla aynı aralığı temel alır:

  • =SUMIF(C2:C13,">500",C2:C13)
  • Formül sonucu: 4,450

Not: COUNTIF ve SUMIF işlevleri joker karakter karşılaştırma işaretlerini de kullanabilir. Daha fazla bilgi için, Excel Yardımı içinden "joker karakter" konusuna bakın.

Birden Fazla Koşul Kullanarak Koşullu Sayma ve Toplama Yapma
Bu bölümdeki formüller iki veya daha fazla koşula göre sayma ve toplama yapar.

Bir Satış Temsilcisinin Satış Yaptığı Ayları Sayma
Bu formül Jones adlı satış temsilcisinin Ocak ayında kaç adet satış yaptığını sayar. Bu, içinde iki koşul kullanılan bir koşullu sayma formülüdür.

  • =SUMPRODUCT((A2:A13="Jones")*(B2:B13="Feb"))
  • Formül sonucu: 2

Tablo 1'de, ayrıntılar görülmektedir. İlk sütunda ifadenin ilk kısmının sonucu, ikinci sütunda ise ifadenin ikinci kısmının sonucu verilmiştir. Son sütunda, ilk iki sütunun çarpımından çıkan sonuç görülmektedir. Her iki sütunda da "TRUE" değeri olduğunda, benzer değerlerin çarpımı 1 olur. Formül daha sonra bu çarpımların toplamını verir.

A2:A13="Jones"

B2:B13="Feb"

Çarpma Sonucu

True

False

0

True

False

0

False

False

0

False

False

0

False

False

0

False

False

0

False

True

0

True

True

1

False

True

0

False

True

0

False

True

0

True

True

1



Satışların Belirli Bir Değerden Yüksek Olduğu Ayları Sayma
Sayısal verilerle çalışmak için, yukarıdakine benzer bir formül kullanabilirsiniz. Bu formül, ayın Ocak olduğu ve miktarın 200'den büyük olduğu satırların sayısını verir.

  • =SUMPRODUCT((B2:B13="Jan")*(C2:C13>200))
  • Formül sonucu: 4

Tutarı Belirli Değerler Arasında Olan Satışları Sayma
Bu formül, satışların 200 ile 500 arasına düştüğü zamanları sayar. Formülde iki koşul kullanılmaktadır: 200'e eşit veya 200'den büyük miktarlar ve 500'e eşit veya 500'den küçük miktarlar.

  • =SUMPRODUCT((C2:C13>=200)*(C2:C13<=500))
  • Formül sonucu: 5

Satışları Üç Ayrı Koşula Göre Sayma
Bu formül, satış temsilcisinin Jones adlı kişi, ayın Şubat ve satış miktarının 500'den büyük olduğu zamanları sayar. Bu işlevde, birlikte çarpılan üç mantıklı ifade içeren tek bir ifade kullanılmaktadır. Sonuç bu öğelerin toplamıdır.

  • =SUMPRODUCT((A2:A13="Jones")*(B2:B13="Feb")*(C2:C13>500))
  • Formül sonucu: 1

Satış Temsilcisinin Belirli Bir Aydaki Satışlarını Toplama
Aşağıdaki formül satış tutarlarını iki koşula göre toplar: satış temsilcisinin Jones adlı kişi ve ayın Şubat olduğu zamanlar.

  • =SUMPRODUCT((A2:A13="Jones")*(B2:B13="Feb")*(C2:C13))
  • Formül sonucu: 1,150

İki Satış Temsilcisinin Satışlarını Birleştirerek Toplama
Aşağıdaki formül Jones ve Rogers adlı satış temsilcilerinin yaptıkları satışların toplamını verir. Formülde, üç ifadeden oluşan tek bir ifade kullanılmaktadır. Ancak, ilk iki ifadenin, önceki örnekte olduğu gibi çarpılmadığına dikkat edin. Çünkü mantıklı bir "VEYA" karşılaştırması yapıyoruz, dolayısıyla bunlar toplanmaktadır. İki mantıklı değer toplanınca, ifadelerden birinin TRUE olması durumunda 1 değerine ulaşılır.

  • =SUMPRODUCT(((A2:A13="Jones")+(A2:A13="Rogers"))*(C2:C13))
  • Formül sonucu: 3,175

 

Yorum Yaz